You are here: Home / Services / Data Analysis and Visualization / Visualization / Software / NCL / source codes / DKRZ NCL plot ICON global data using CellFill mode

DKRZ NCL plot ICON global data using CellFill mode

This examples shows how to use the CellFill mode to plot the global ICON data instead of drawing polygons.

Example script:

;--------------------------------------------------------------------
; DKSR NCL example:      contour_plot_ICON_global_CellFill.ncl
;
; Description:           plot global ICON data using CellFill mode
;
; 18.06.18 kmf
;--------------------------------------------------------------------
begin

  r2d  = get_r2d("float")
 
  f = addfile("lkm1003_tas.nc","r")
 
  tas            =  f->tas
 
  clat           =  f->clat * r2d
  clat@units     = "degrees_north"
  clat@long_name = "latitude"
 
  clon           =  f->clon * r2d
  clon@units     = "degrees_east"
  clon@long_name = "longitude"

  clatbnds       =  f->clat_bnds * r2d
  clonbnds       =  f->clon_bnds * r2d
 
  wks_type          = "png"
  wks_type@wkWidth  =  1200
  wks_type@wkHeight =  1200
  wks = gsn_open_wks(wks_type,"plot_ICON_DYAMOND_tas_global")

  res                   =  True
  res@cnFillPalette     = "WhiteBlueGreenYellowRed" ;-- choose colormap - no white
  res@cnFillOn          =  True
  res@cnLinesOn         =  False
  res@cnInfoLabelOn     =  False
  res@cnFillMode        = "CellFill"

  res@sfXArray          =  clon
  res@sfYArray          =  clat
  res@sfXCellBounds     =  clonbnds
  res@sfYCellBounds     =  clatbnds

  res@tiMainString      = "ICON: contour plot using CellFill "

  plot = gsn_csm_contour_map(wks,tas(0,0,:),res)
 
end

Document Actions